10 WIDTH 80,25:CONSOLE 1,25,0,1:PRINT CHR$(12)
20 LOCATE 0,0:COLOR 4:PRINT "SAVE : 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F"
30 COLOR 7

100 '
110 C=&hB:GOSUB 1000:                   'SEND MEMORY
120 C=&h0:GOSUB 1100:      GOSUB 1100:  '$0000
130 C=&h8:GOSUB 1100:C=&h0:GOSUB 1100:  '$07FF

200 '
210 FOR AD=&hD000 TO &hD7FF STEP 16
220  PRINT HEX$(AD)+" :";
230  FOR A=AD TO AD+15
240   OUT &HFF,&HB:                     'RFD=1
250   IF (INP(&HFE) AND 1)=0 THEN 250   'DAV=1?
260   OUT &HFF,&HA:                     'RFD=0
270   D=INP(&HFC)                       'DATA
280   IF D<16 THEN PRINT" 0"+HEX$(D);ELSE PRINT" "+HEX$(D);
290   POKE A,D
300   OUT &HFF,&HD:                     'DAC=1
310   IF (INP(&HFE) AND 1)=1 THEN 310   'DAV=0?
320   OUT &HFF,&HC:                     'DAC=0
330  NEXT A
340  PRINT
350 NEXT AD
360 END

1000 'command
1010 OUT &hFE,&h80:                     'ATN=1
1020 IF (INP(&hFE) AND 2)=0 THEN 1020:  'RFD=1?
1030 OUT &hFE,&h0:                      'ATN=0
1040 GOTO 1200
1100 'data
1110 IF (INP(&hFE) AND 2)=0 THEN 1110:  'RFD=1?
1200 'common
1220 OUT &HFD,C:                        'COMMAND/DATA
1230 OUT &hFF,&h9:                      'DAV=1
1240 IF (INP(&hFE) AND 4)=0 THEN 1240:  'DAC=1?
1250 OUT &hFF,&h8:                      'DAV=0
1260 IF (INP(&hFE) AND 4)=4 THEN 1260:  'DAC=0?
1270 RETURN